Awscloudtrail Activity With Monitored Aws Account Root User

KQL detection rule by ep3p · MIT

No description provided

let _AWSAccounts =
    _GetWatchlist("AccountId-AuditAWSAccounts")
    | project AccountId, AccountName, Auditors = Auditor, AlertSeverity = Severity, Notes
;
AWSCloudTrail
| where UserIdentityType == "Root"
| summarize
    StartTime = min(TimeGenerated),
    EndTime = max(TimeGenerated),
	SourceIpAddresses = array_sort_asc(make_set_if(SourceIpAddress, isnotempty(SourceIpAddress))),
    SessionMfaAuthenticated = make_set_if(SessionMfaAuthenticated, isnotempty(SessionMfaAuthenticated)),
    EventNames = array_sort_asc(make_set(EventName)),
    ReadOnly = make_set_if(ReadOnly, isnotempty(ReadOnly)),
    ManagementEvent = make_set_if(ManagementEvent, isnotempty(ManagementEvent)),
    ErrorCodes = make_set_if(ErrorCode, isnotempty(ErrorCode)),
    ErrorMessages = make_set_if(ErrorMessage, isnotempty(ErrorMessage)),
    UserAgents = make_set_if(UserAgent, isnotempty(UserAgent)),
    take_any(UserIdentityType)
    by UserIdentityPrincipalid, UserIdentityArn, UserIdentityAccountId, RecipientAccountId
| lookup kind=leftouter _AWSAccounts on $left.UserIdentityAccountId == $right.AccountId
| where not(isnotempty(AccountName) and not(Notes has "[RootActivity]"))
| mv-apply SourceIpAddress = SourceIpAddresses to typeof(string) on (
    summarize AddressesList = strcat_array(array_sort_asc(make_set_if(SourceIpAddress, not(SourceIpAddress has ".amazonaws.com"))), '\n\n- ')
    )
| extend AlertDescription = strcat(
    'This rule detects operations of the root user in AWS accounts, which should be avoided.\n\nThe root user was used in the AWS account "',
    iff(isnotempty(AccountName), AccountName, RecipientAccountId),
    '".\n\nThe operations were made from the addresses:\n\n- ',
    AddressesList,
    '\n'
    )
| project
    StartTime,
    EndTime,
    UserIdentityAccountName = AccountName,
    UserIdentityAccountId,
    UserIdentityPrincipalid,
    UserIdentityArn,
    UserIdentityType,
    RecipientAccountId,
    SourceIpAddresses,
    SessionMfaAuthenticated,
    EventNames,
    ReadOnly,
    ManagementEvent,
    ErrorCodes,
    ErrorMessages,
    UserAgents,
    AlertSeverity,
    AlertDescription,
    Auditors

[[ currentRule.title && currentRule.title.length > 60 ? currentRule.title.slice(0, 60) + '…' : currentRule.title ]]

80e09721-1f99-453f-a915-94e7fc4c2ea8

Propose edits, view related rules, and engage with the community through comments.

Executable code, not a declarative rule

This submission is arbitrary [[ currentRule.format ? currentRule.format.toUpperCase() : '' ]] code, not a declarative detection rule — review it as you would any script before running it, and note that it cannot be safely aggregated or auto-executed alongside YARA/Sigma/Suricata/CRS rules.

Rejected pattern present

[[ reason ]]

What does this mean?

Format & documentation suggestions

Not a security issue — this rule is valid and was accepted as-is. These are optional fields/conventions its own format recommends, mainly affecting its quality score and how well it documents itself for other reviewers.

[[ reason ]]

What do these messages mean?

[[ currentRule.title && currentRule.title.length > 60 ? currentRule.title.slice(0, 60) + '…' : currentRule.title ]]

[[ currentRule.title ]]

Community Discussion