Externaldata Microsoft Graph Permissions

KQL detection rule by ep3p · MIT

No description provided

let _DelegatedGraphPermissions = materialize(
    externaldata(AdminConsentDescription:string, AdminConsentDisplayName:string, Id:string, IsEnabled:bool, Origin:string, Type:string, UserConsentDescription:string, UserConsentDisplayName:string, Value:string, AdditionalProperties:dynamic)
    [@'https://raw.githubusercontent.com/merill/microsoft-info/refs/heads/main/_info/GraphDelegateRoles.json']
    with(format='multijson')
    | project
        PermissionName = Value,
        DelegatedPermissionId = Id,
        DelegatedPermissionType = Type,
        UserConsentDisplayName,
        UserConsentDescription,
        AdminConsentDisplayName,
        AdminConsentDescription
);
let _ApplicationGraphPermissions = materialize(
    externaldata(AllowedMemberTypes:dynamic, Description:string, DisplayName:string, Id:string, IsEnabled:bool, Origin:string, Value:string, AdditionalProperties:dynamic)
    [@'https://raw.githubusercontent.com/merill/microsoft-info/refs/heads/main/_info/GraphAppRoles.json']
    with(format='multijson')
    | project
        PermissionName = Value,
        ApplicationPermissionId = Id,
        ApplicationPermissionDisplayName = DisplayName,
        ApplicationPermissionDescription = Description
);
let _GraphPermissionsCustomClassification = materialize(
    externaldata(AppId: string, AppRoleId: string, AppRoleDisplayName: string, Category: string, EAMTierLevelName: string)//, EAMTierLevelTagValue: int)
    [@"https://raw.githubusercontent.com/Cloud-Architekt/AzurePrivilegedIAM/main/Classification/Classification_AppRoles.json"]
    with(format='multijson')
    | project
        ApplicationPermissionId = AppRoleId,
        PermissionName = AppRoleDisplayName,
        Category,
        EAMTierLevelName
);
_ApplicationGraphPermissions
| join kind=fullouter _GraphPermissionsCustomClassification on ApplicationPermissionId
| project-away *1
| join kind=fullouter _DelegatedGraphPermissions on PermissionName
| extend
    PermissionName = iff(isnotempty(PermissionName), PermissionName, PermissionName1),
    PermissionAPI = "Microsoft Graph",
    ConsentRisk = ""
| sort by DelegatedPermissionType == "User" desc, PermissionName asc
| project
    PermissionAPI,
    PermissionName,
    ConsentRisk,
    DelegatedPermissionId,
    DelegatedPermissionType,
    UserConsentDisplayName,
    UserConsentDescription,
    AdminConsentDisplayName,
    AdminConsentDescription,
    ApplicationPermissionId,
    ApplicationPermissionDisplayName,
    ApplicationPermissionDescription,
    Category,
    EAMTierLevelName

[[ currentRule.title && currentRule.title.length > 60 ? currentRule.title.slice(0, 60) + '…' : currentRule.title ]]

d6564e42-0b0b-4b72-910e-6ea33d3700f1

Propose edits, view related rules, and engage with the community through comments.

Executable code, not a declarative rule

This submission is arbitrary [[ currentRule.format ? currentRule.format.toUpperCase() : '' ]] code, not a declarative detection rule — review it as you would any script before running it, and note that it cannot be safely aggregated or auto-executed alongside YARA/Sigma/Suricata/CRS rules.

Rejected pattern present

[[ reason ]]

What does this mean?

Format & documentation suggestions

Not a security issue — this rule is valid and was accepted as-is. These are optional fields/conventions its own format recommends, mainly affecting its quality score and how well it documents itself for other reviewers.

[[ reason ]]

What do these messages mean?

[[ currentRule.title && currentRule.title.length > 60 ? currentRule.title.slice(0, 60) + '…' : currentRule.title ]]

[[ currentRule.title ]]

Community Discussion